刪Autorun病毒關鍵是要干掉正在跑的木馬進程。這種木馬確實有點難搞，能被任務管理器結束掉的還好說。但你這情況看起來像是遇到了高級點的木馬，連殺毒軟件和任務管理器都能給你關了，挺麻煩。
實在不行可以找個能看進程的任務管理器工具，改個名字運行試試，用它來查系統文件夾里的木馬，先結束進程再刪文件。
建議進安全模式操作，用WinRAR打開各個盤符根目錄看看都有啥文件。重點是autorun.inf這個文件，它不是病毒本身，但里面藏著木馬的信息，你可以打開瞧瞧內容。
千萬注意別亂點根目錄下的其他可疑文件或程序，那基本就是罪魁禍首。比對一下各盤的autorun.inf內容，基本能找出對應木馬。
系統文件夾里可能還藏有隱藏木馬路徑，autorun.inf里也能看出點線索。能刪多少刪多少，同時把啟動項里的木馬啟動也給關了。
要是方便的話，可以把autorun.inf的內容貼出來，大家一起幫你瞅瞅。

@Echo Off
color 2f
title Autorun 病毒清除工具-By Phexon
Rem 殺進程
taskkill /F /IM SocksA.exe /IM SVOHOST.exe /IM AdobeR.exe /IM ravmone.exe /IM wincfgs.exe /IM doc.exe /IM rose.exe /IM sxs.exe /IM autorun.exe /IM KB20060111.exe /IM tel.xls.exe>nul 2>nul

:clearauto
cls
Echo.
Echo Autorun 病毒清除工具
Echo.
Echo.
Echo.
Echo 制作：然丶似水流年
Echo.
Echo 本程序運行后自動清除每個盤符下面的Autorun病毒
Echo 本程序原理是基于讀取每個盤符下的Autorun.inf相關字段
Echo.
Echo [1] 僅僅刪除所有盤符下的 Autorun 病毒
Echo [2] 刪除所有盤符下的 Autorun 病毒并且建立同名免疫目錄(推薦!)
Echo [3] 禁用系統的 Autorun 機制以避免 Autorun 病毒的再次感染
Echo [4] 取消所有盤符的 Autorun 病毒免疫
Echo [5] 刪除并免疫指定盤符的 Autorun 病毒
Echo [6] 取消免疫指定盤符
Echo [7] 恢復相關注冊表項默認值
Echo [0] 退出
Echo [*] 然丶似水流年友情提供, 百度HI
Echo.
Set /p clearslt= 請輸入您的選擇(1/2/3/4/5/6/7/0):
If "%clearslt%"=="" Goto clearauto
If "%clearslt%"=="1" Goto clearauto1
If "%clearslt%"=="2" Goto clearauto2
If "%clearslt%"=="3" Goto clearauto3
If "%clearslt%"=="4" Goto clearauto4
If "%clearslt%"=="5" Goto clearauto5
If "%clearslt%"=="6" Goto clearauto6
If "%clearslt%"=="7" Goto clearauto7
If "%clearslt%"=="0" Exit

:clearauto1
taskkill /F /IM SocksA.exe /IM SVOHOST.exe /IM AdobeR.exe /IM ravmone.exe /IM wincfgs.exe /IM doc.exe /IM rose.exe /IM sxs.exe /IM autorun.exe /IM KB20060111.exe /IM tel.xls.exe>nul 2>nul
For %%a In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do (
fsutil fsinfo drivetype %%a: |find /i "固定驅動器" && (
For /f "tokens=2 delims==" %%b In (%%a:\autorun.inf) Do Del /a /f /q "%%a:\%%b" >nul 2>nul
Del /a /f /q %%a:\autorun.inf >nul 2>nul
) >nul 2>nul
fsutil fsinfo drivetype %%a: |find /i "可移動驅動器" && (
For /f "tokens=2 delims==" %%b In (%%a:\autorun.inf) Do Del /a /f /q "%%a:\%%b" >nul 2>nul
Del /a /f /q %%a:\autorun.inf >nul 2>nul
) >nul 2>nul
)
cls
Echo Autorun 病毒清除完畢，任意鍵返回……
pause>nul
Goto clearauto

:clearauto2
taskkill /F /IM SocksA.exe /IM SVOHOST.exe /IM AdobeR.exe /IM ravmone.exe /IM wincfgs.exe /IM doc.exe /IM rose.exe /IM sxs.exe /IM autorun.exe /IM KB20060111.exe /IM tel.xls.exe>nul 2>nul
For %%a In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do (
fsutil fsinfo drivetype %%a: |find /i "固定驅動器" && (
For /f "tokens=2 delims==" %%b In (%%a:\autorun.inf) Do Del /a /f /q "%%a:\%%b" & md "%%a:\%%b\免疫目錄不要刪除!...\" & attrib +s +h +r "%%a:\%%b" & Echo Y|cacls "%%a:\%%b" /T /C /P everyone:N >nul 2>nul
Del /a /f /q %%a:\autorun.inf & md "%%a:\autorun.inf\免疫目錄不要刪除!...\" & attrib +s +h +r %%a:\autorun.inf & Echo Y|cacls "%%a:\autorun.inf" /T /C /P everyone:N >nul 2>nul
) >nul 2>nul
fsutil fsinfo drivetype %%a: |find /i "可移動驅動器" && (
For /f "tokens=2 delims==" %%b In (%%a:\autorun.inf) Do Del /a /f /q "%%a:\%%b" & md "%%a:\%%b\免疫目錄不要刪除!...\" & attrib +s +h +r "%%a:\%%b" & Echo Y|cacls "%%a:\%%b" /T /C /P everyone:N >nul 2>nul
Del /a /f /q %%a:\autorun.inf & md "%%a:\autorun.inf\免疫目錄不要刪除!...\" & attrib +s +h +r %%a:\autorun.inf & Echo Y|cacls "%%a:\autorun.inf" /T /C /P everyone:N >nul 2>nul
) >nul 2>nul
)
cls
Echo Autorun 病毒清除并免疫完畢，任意鍵返回……
pause>nul
Goto clearauto

:clearauto3
cls
Echo.
Echo 正在停止相關服務……
Echo.
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\policies\Explorer" /v NoDriveTypeAutoRun /t REG_DWORD /d 0x000000ff /f >nul 2>nul
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\policies\Explorer" /v NoDriveTypeAutoRun /t REG_DWORD /d 0x000000ff /f >nul 2>nul
net stop ShellHWDetection >nul 2>nul
sc config ShellHWDetection start= disabled >nul 2>nul
Rem 添加防止從回收站或仿回收站的目錄中直接運行可執行文件的策略
Set REGPATH=HKLM\SOFTWARE\Policies\Microsoft\Windows\Safer\CodeIdentifiers\0\Paths
Set SFLAG=/v SaferFlags /t REG_DWORD /d 0x00000000 /f
Set IDATA=/f /v ItemData /d "?:\Recyc?
reg add %REGPATH%\{00ffa5bf-abe7-4901-aacf-4f58aa31217a} %SFLAG%>nul
reg add %REGPATH%\{00ffa5bf-abe7-4901-aacf-4f58aa31217a} %IDATA%\*\*\*\*.*">nul

reg add %REGPATH%\{41fe7eed-c47a-46f6-840a-240796fd03cf} %SFLAG%>nul
reg add %REGPATH%\{41fe7eed-c47a-46f6-840a-240796fd03cf} %IDATA%\*\*\*.*">nul

reg add %REGPATH%\{4e93c91c-a40e-462e-9b89-3b0832d222d9} %SFLAG%>nul
reg add %REGPATH%\{4e93c91c-a40e-462e-9b89-3b0832d222d9} %IDATA%\*.*">nul

reg add %REGPATH%\{5bfc100b-d3fb-450e-88ec-6819ab56a9ff} %SFLAG%>nul
reg add %REGPATH%\{5bfc100b-d3fb-450e-88ec-6819ab56a9ff} %IDATA%\*\*\*\*.*">nul

reg add %REGPATH%\{5c5e2bcd-7057-43f4-830c-e4361d2afadd} %SFLAG%>nul
reg add %REGPATH%\{5c5e2bcd-7057-43f4-830c-e4361d2afadd} %IDATA%\*.*">nul

reg add %REGPATH%\{5f8ff865-0638-4c6e-98de-923e7bc6b330} %SFLAG%>nul
reg add %REGPATH%\{5f8ff865-0638-4c6e-98de-923e7bc6b330} %IDATA%\*\*\*.*">nul

reg add %REGPATH%\{649c1429-0e79-453c-abe9-b5682e035ae7} %SFLAG%>nul
reg add %REGPATH%\{649c1429-0e79-453c-abe9-b5682e035ae7} %IDATA%\*\*.*">nul

reg add %REGPATH%\{718f54b2-c669-4d7b-aeff-18d69f100034} %SFLAG%>nul
reg add %REGPATH%\{718f54b2-c669-4d7b-aeff-18d69f100034} %IDATA%\*\*.*">nul

reg add %REGPATH%\{8385d9d2-80c9-4ac1-a100-ed3e62863d97} %SFLAG%>nul
reg add %REGPATH%\{8385d9d2-80c9-4ac1-a100-ed3e62863d97} %IDATA%\*.*">nul

reg add %REGPATH%\{af2a4fcf-441c-421e-9663-52cd3502cfd7} %SFLAG%>nul
reg add %REGPATH%\{af2a4fcf-441c-421e-9663-52cd3502cfd7} %IDATA%\*\*\*.*">nul

reg add %REGPATH%\{b997f4b2-c037-4e97-b051-31f5d86df802} %SFLAG%>nul
reg add %REGPATH%\{b997f4b2-c037-4e97-b051-31f5d86df802} %IDATA%\*\*.*">nul

reg add %REGPATH%\{d4e7b6ff-d76f-407f-b8bb-ea0835f5babc} %SFLAG%>nul
reg add %REGPATH%\{d4e7b6ff-d76f-407f-b8bb-ea0835f5babc} /f /v ItemData /d "RECYC*.*">nul

Rem 清除喜歡利用回收站的移動磁盤自動運行病毒
For %%a In (c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z) Do (
For %%b In (exe pif com) Do (
Echo Y|cacls "%%a:\Recycler\*.%%b" /C /T /P everyone:F>nul 2>nul&Echo Y|cacls "%%a:\Recycled\*.%%b" /C /T /P everyone:F>nul 2>nul&Echo Y|cacls "%%a:\Recycled\Recycled\*.%%b" /C /T /P everyone:F>nul 2>nul
Del /A /F /S /Q "%%a:\Recycler\*.%%b">nul 2>nul&Del /A /F /S /Q "%%a:\Recycled\*.%%b">nul 2>nul&Del /A /F /S /Q "%%a:\Recycled\Recycled\*.%%b">nul 2>nul
)
)>nul 2>nul
Echo.
Echo 相關服務已停止并禁用，任意鍵返回……
pause >nul
Goto clearauto

:clearauto4
For %%a In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do (
fsutil fsinfo drivetype %%a: |find /i "固定驅動器" && (
cacls "%%a:\autorun.inf" /T /C /P everyone:F&Del /a /f /q "%%a:\autorun.inf" & rd /s /q "%%a:\autorun.inf">nul 2>nul
)>nul 2>nul
fsutil fsinfo drivetype %%a: |find /i "可移動驅動器" && (
cacls "%%a:\autorun.inf" /T /C /P everyone:F&Del /a /f /q "%%a:\autorun.inf" & rd /s /q "%%a:\autorun.inf">nul 2>nul
)>nul 2>nul
)
cls
Echo.
Echo 已經解除全部盤符的免疫，任意鍵返回……
pause>nul
Goto clearauto

:clearauto5
cls
Echo.
Set /p pf= 請輸入盤符，如"F:"(不包括引號)
Echo 即將免疫%pf%盤……|find /i ":"||Set pf=%pf%:&&Echo 即將免疫%pf%盤……
taskkill /F /IM SocksA.exe /IM SVOHOST.exe /IM AdobeR.exe /IM ravmone.exe /IM wincfgs.exe /IM doc.exe /IM rose.exe /IM sxs.exe /IM autorun.exe /IM KB20060111.exe /IM tel.xls.exe>nul 2>nul
fsutil fsinfo drivetype %pf% |find /i "固定驅動器" && (
For /f "tokens=2 delims==" %%a In (%pf%\autorun.inf) Do Del /a /f /q "%pf%\%%a" & md "%pf%\%%a\免疫目錄不要刪除!...\" & attrib +s +h +r "%pf%\%%a" & Echo Y|cacls "%pf%\%%a" /T /C /P everyone:N >nul 2>nul
Del /a /f /q %pf%\autorun.inf & md "%pf%\autorun.inf\免疫目錄不要刪除!...\" & attrib +s +h +r %pf%\autorun.inf & Echo Y|cacls "%pf%\autorun.inf" /T /C /P everyone:N >nul 2>nul
Goto DoneclearAuto
) >nul 2>nul
fsutil fsinfo drivetype %pf% |find /i "可移動驅動器" && (
For /f "tokens=2 delims==" %%a In (%pf%\autorun.inf) Do Del /a /f /q "%pf%\%%a" & md "%pf%\%%a\免疫目錄不要刪除!...\" & attrib +s +h +r "%pf%\%%a" & Echo Y|cacls "%pf%\%%a" /T /C /P everyone:N >nul 2>nul
Del /a /f /q %pf%\autorun.inf & md "%pf%\autorun.inf\免疫目錄不要刪除!...\" & attrib +s +h +r %pf%\autorun.inf & Echo Y|cacls "%pf%\autorun.inf" /T /C /P everyone:N >nul 2>nul
Goto DoneclearAuto
) >nul 2>nul
Echo.
Echo 您所輸入的盤符不存在或者是只讀設備，
Echo 請重新輸入
Goto clearauto5

:DoneclearAuto
cls
Echo.
Echo 指定的磁盤 %pf% 已經成功進行了 Autorun 病毒的清除及免疫
Echo.
Echo [1] 繼續免疫其他磁盤
Echo [0] 返回主菜單
Set /p choice= 請輸入您的選擇(1/0):
If %choice%="" Goto DoneclearAuto
If %choice%="1" Goto clearauto5
If %choice%="0" Goto clearauto

:clearauto6
cls
Echo.
Set /p pf= 請輸入盤符，如"F:"(不包括引號)
Echo 即將取消免疫%pf%盤……|find /i ":"||Set pf=%pf%:&&Echo 即將取消免疫%pf%盤……
fsutil fsinfo drivetype %pf% |find /i "固定驅動器" && (
cacls "%pf%\autorun.inf" /T /C /P everyone:F&Del /a /f /q "%pf%\autorun.inf" & rd /s /q "%pf%\autorun.inf">nul 2>nul
Goto DoneUnauto
)>nul 2>nul
fsutil fsinfo drivetype %pf% |find /i "可移動驅動器" && (
cacls "%pf%\autorun.inf" /T /C /P everyone:F&Del /a /f /q "%pf%\autorun.inf" & rd /s /q "%pf%\autorun.inf">nul 2>nul
Goto DoneUnauto
)>nul 2>nul
Echo.
Echo 您所輸入的盤符不存在或者是只讀設備，
Echo 請重新輸入
Goto clearauto6

:DoneUnauto
cls
Echo.
Echo 指定的磁盤 %pf% 已經成功解除了 Autorun 病毒免疫
Echo.
Echo [1] 繼續解除免疫其他磁盤
Echo [0] 返回主菜單
Set choice=
Set /p choice= 請輸入您的選擇(1/0):
If %choice%="" Goto DoneUnauto
If %choice%="1" Goto clearauto6
If %choice%="0" Goto clearauto

:clearauto7
cls
Rem 防止在資源管理器中徹底隱藏文件、禁止文件等
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL" /v CheckedValue /t REG_DWORD /d 0x00000001 /f>nul 2>nul
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2" /f>nul 2>nul
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer\DisallowRun" /f>nul 2>nul
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v DisallowRun /f>nul 2>nul
Rem 防止轉移啟動組位置
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v Startup /d "%USERPROFILE%\「開始」菜單\程序\啟動" /f>nul 2>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Common Startup" /d "%ALLUSERSPROFILE%\「開始」菜單\程序\啟動" /f>nul 2>nul
Echo.
Echo 相關注冊表恢復完畢，任意鍵返回……
pause>nul
Goto clearauto

以上復制,保存為.BAT

您可以全盤查殺病毒即可。

　隨著網絡辦公范圍的普及以及個人需要處理事務的增加，U盤已經成為人們工作生活中很難割舍的一部分，將大量重要的數據、資料存放在小巧輕便的U盤中已經成了很多人的習慣。但令人頭疼的問題是，在急需空間存放大型數據、資料或游戲程序時，總會陷入U盤無法格式化的窘境。 　　鑒于大量用戶通過論壇與QQ反饋群反應："為什么U盤無法格式化"、"新買的U盤無法完成格式化？"等一系列問題，金山衛士應急小組深入分析了該問題的成因。緊急更新"金山衛士U盤修復工具"增加了"強力格式化U盤"與"重啟格式化U盤"功能為廣大網友排憂解難。從根本上解決了無法格式化U盤的難題。立即下載>>

AUTO是U盤病毒。建議下載個AUTO專殺工具。我碰過類似情況

卡巴就可以殺